newlib: update

git-svn-id: svn://kolibrios.org@1906 a494cfbc-eb01-0410-851d-a64ba20cac60
2011-03-11 18:52:24 +00:00
parent a316fa7c9d
commit 2336060a0c
297 changed files with 26930 additions and 2094 deletions
@@ -0,0 +1,49 @@
+/*
+ * Written by J.T. Conklin <jtc@netbsd.org>.
+ * Public domain.
+ */
+
+/* e^x = 2^(x * log2(e)) */
+
+  .file "exp.s"
+	.text
+	.p2align 4,,15
+
+.globl _exp
+.def   _exp;  .scl  2;  .type 32; .endef
+
+_exp:
+
+      fldl  4(%esp)
+/* I added the following ugly construct because exp(+-Inf) resulted
+   in NaN.  The ugliness results from the bright minds at Intel.
+   For the i686 the code can be written better.
+   -- drepper@cygnus.com.  */
+    fxam        /* Is NaN or +-Inf?  */
+    fstsw %ax
+    movb  $0x45, %dh
+    andb  %ah, %dh
+    cmpb  $0x05, %dh
+    je  1f      /* Is +-Inf, jump.  */
+
+    fldl2e
+    fmulp       /* x * log2(e) */
+    fld %st
+    frndint       /* int(x * log2(e)) */
+    fsubr %st,%st(1)    /* fract(x * log2(e)) */
+    fxch
+    f2xm1       /* 2^(fract(x * log2(e))) - 1 */
+    fld1
+    faddp       /* 2^(fract(x * log2(e))) */
+    fscale        /* e^x */
+    fstp  %st(1)
+    ret
+
+1:
+    testl $0x200, %eax    /* Test sign.  */
+    jz  2f      /* If positive, jump.  */
+
+    fstp  %st
+    fldz        /* Set result to 0.  */
+2:
+    ret