aabc2/KOS_qrcodes
1
0
Fork 0
forked from KolibriOS/kolibrios
Code Pull Requests Activity

Changed structure of svn repository

Browse Source 
git-svn-id: svn://kolibrios.org@109 a494cfbc-eb01-0410-851d-a64ba20cac60
This commit is contained in:
heavyiron
2006-07-28 13:39:16 +00:00
parent 5aa9386dcc
commit 630234432f
673 changed files with 20707 additions and 28013 deletions
Download Patch File Download Diff File Expand all files Collapse all files
programs/develop/hexview/trunk/build_en.bat
+4
View File
@@ -0,0 +1,4 @@
@erase lang.inc
@echo lang fix en >lang.inc
@fasm hexview.asm hexview
@pause
programs/develop/hexview/trunk/build_ru.bat
+4
View File
@@ -0,0 +1,4 @@
@erase lang.inc
@echo lang fix ru >lang.inc
@fasm hexview.asm hexview
@pause
programs/develop/hexview/trunk/hexview.asm
+219
View File
@@ -0,0 +1,219 @@
;
; EXAMPLE APPLICATION
;
; Compile with FASM for Menuet
;
use32
org 0x0
db 'MENUET00' ; 8 byte id
dd 38 ; required os
dd START ; program start
dd I_END ; program image size
dd 0x8000 ; required amount of memory
dd 0x8000 ; esp = 0x7FFF0
dd 0x00000000 ; reserved=no extended header
include 'lang.inc'
include 'macros.inc'
begin dd 0
START: ; start of execution
call open_file
red:
call draw_window ; at first, draw the window
still:
mov eax,10 ; wait here for event
int 0x40
dec eax ; redraw request ?
je red
dec eax ; key in buffer ?
je key
dec eax ; button in buffer ?
je button
jmp still
; red: ; redraw
; call draw_window
; jmp still
key: ; key
mov eax,2 ; just read it and ignore
int 0x40
jmp still
button: ; button
mov eax,17 ; get id
int 0x40
cmp ah,3
jne no_up
cmp [begin],16
jb no_up
add [begin],-16
jmp red
no_up:
cmp ah,4
jne no_down
add [begin],16
jmp red
no_down:
dec ah ; button id=1 ?
jne still
xor eax,eax ; close this program
dec eax
int 0x40
; *********************************************
; ******* WINDOW DEFINITIONS AND DRAW ********
; *********************************************
draw_window:
mov eax,12 ; function 12:tell os about windowdraw
mov ebx,1 ; 1, start of draw
int 0x40
; DRAW WINDOW
xor eax,eax ; function 0 : define and draw window
mov ebx,100*65536+400 ; [x start] *65536 + [x size]
mov ecx,100*65536+270 ; [y start] *65536 + [y size]
mov edx,0x03224466 ; color of work area RRGGBB,8->c
mov esi,0x006688aa ; color of grab bar RRGGBB,8->color gl
mov edi,0x00ffffff ; color of frames RRGGBB
int 0x40
; WINDOW LABEL
mov eax,4 ; function 4 : write text to window
mov ebx,8*65536+8 ; [x start] *65536 + [y start]
mov ecx,0x00ffffff ; color of text RRGGBB
mov edx,labelt ; pointer to text beginning
mov esi,labellen-labelt ; text length
int 0x40
mov eax,8
mov ebx,280*65536+16*6
mov ecx,240*65536+14
mov edx,2
mov esi,0x5599cc
int 0x40
mov ebx,15*65536+125
inc edx
int 0x40
add ebx,127*65536
inc edx
int 0x40
mov eax,4
mov ebx,15*65536+243
mov ecx,0xffffff
mov edx,buttons
mov esi,blen-buttons
int 0x40
mov ebx,280*65536+35 ; draw info text with function 4
mov ecx,0xffffff
mov edx,text
add edx,[begin]
mov esi,16
mov edi,esi
newline:
push ebx ; hext
push edx
push edi
mov edi,16
mov ecx,edx
mov edx,ebx
add edx,-265*65536
mov eax,47
mov ebx,0x00020101
mov esi,0xffff00
newhex:
; mov ebx,0x00020101
; mov esi,0xffff00
int 0x40
add edx,16*65536
inc ecx
dec edi
jne newhex
; popa
pop edi
pop edx
pop ebx
mov eax,4 ; text
mov esi,16
mov ecx,0xffffff
int 0x40
add ebx,12
add edx,16
dec edi
jnz newline
mov eax,12 ; function 12:tell os about windowdraw
mov ebx,2 ; 2, end of draw
int 0x40
ret
file_name db 'EXAMPLE.ASM '
; db 'EXAMPLE '
open_file:
pusha
mov eax,6
mov ebx,file_name
xor ecx,ecx
mov edx,-1
mov esi,text
int 0x40
popa
ret
; DATA AREA
labelt: db 'HEXVIEW'
labellen:
buttons db ' UP DOWN'
db ' EXAMPLE '
blen:
text:
I_END:
programs/develop/hexview/trunk/macros.inc
+265
View File
@@ -0,0 +1,265 @@
; new application structure
macro meos_app_start
{
use32
org 0x0
db 'MENUET01'
dd 0x01
dd __start
dd __end
dd __memory
dd __stack
if used __params & ~defined __params
dd __params
else
dd 0x0
end if
dd 0x0
}
MEOS_APP_START fix meos_app_start
macro code
{
__start:
}
CODE fix code
macro data
{
__data:
}
DATA fix data
macro udata
{
if used __params & ~defined __params
__params:
db 0
__end:
rb 255
else
__end:
end if
__udata:
}
UDATA fix udata
macro meos_app_end
{
align 32
rb 2048
__stack:
__memory:
}
MEOS_APP_END fix meos_app_end
; macro for defining multiline text data
struc mstr [sstring]
{
forward
local ssize
virtual at 0
db sstring
ssize = $
end virtual
dd ssize
db sstring
common
dd -1
}
; strings
macro sz name,[data] { ; from MFAR [mike.dld]
common
if used name
label name
end if
forward
if used name
db data
end if
common
if used name
.size = $-name
end if
}
macro lsz name,[lng,data] { ; from MFAR [mike.dld]
common
if used name
label name
end if
forward
if (used name)&(lang eq lng)
db data
end if
common
if used name
.size = $-name
end if
}
; easy system call macro
macro mpack dest, hsrc, lsrc
{
if (hsrc eqtype 0) & (lsrc eqtype 0)
mov dest, (hsrc) shl 16 + lsrc
else
if (hsrc eqtype 0) & (~lsrc eqtype 0)
mov dest, (hsrc) shl 16
add dest, lsrc
else
mov dest, hsrc
shl dest, 16
add dest, lsrc
end if
end if
}
macro __mov reg,a { ; mike.dld
if ~a eq
mov reg,a
end if
}
macro mcall a,b,c,d,e,f { ; mike.dld
__mov eax,a
__mov ebx,b
__mov ecx,c
__mov edx,d
__mov esi,e
__mov edi,f
int 0x40
}
; optimize the code for size
__regs fix <eax,ebx,ecx,edx,esi,edi,ebp,esp>
macro add arg1,arg2
{
if (arg2 eqtype 0)
if (arg2) = 1
inc arg1
else
add arg1,arg2
end if
else
add arg1,arg2
end if
}
macro sub arg1,arg2
{
if (arg2 eqtype 0)
if (arg2) = 1
dec arg1
else
sub arg1,arg2
end if
else
sub arg1,arg2
end if
}
macro mov arg1,arg2
{
if (arg1 in __regs) & (arg2 eqtype 0)
if (arg2) = 0
xor arg1,arg1
else if (arg2) = 1
xor arg1,arg1
inc arg1
else if (arg2) = -1
or arg1,-1
else if (arg2) > -128 & (arg2) < 128
push arg2
pop arg1
else
mov arg1,arg2
end if
else
mov arg1,arg2
end if
}
macro struct name
{
virtual at 0
name name
sizeof.#name = $ - name
end virtual
}
; structures used in MeOS
struc process_information
{
.cpu_usage dd ? ; +0
.window_stack_position dw ? ; +4
.window_stack_value dw ? ; +6
.not_used1 dw ? ; +8
.process_name rb 12 ; +10
.memory_start dd ? ; +22
.used_memory dd ? ; +26
.PID dd ? ; +30
.x_start dd ? ; +34
.y_start dd ? ; +38
.x_size dd ? ; +42
.y_size dd ? ; +46
.slot_state dw ? ; +50
rb (1024-52)
}
struct process_information
struc system_colors
{
.frame dd ?
.grab dd ?
.grab_button dd ?
.grab_button_text dd ?
.grab_text dd ?
.work dd ?
.work_button dd ?
.work_button_text dd ?
.work_text dd ?
.work_graph dd ?
}
struct system_colors
; constants
; events
EV_IDLE = 0
EV_TIMER = 0
EV_REDRAW = 1
EV_KEY = 2
EV_BUTTON = 3
EV_EXIT = 4
EV_BACKGROUND = 5
EV_MOUSE = 6
EV_IPC = 7
EV_STACK = 8
; event mask bits for function 40
EVM_REDRAW = 1b
EVM_KEY = 10b
EVM_BUTTON = 100b
EVM_EXIT = 1000b
EVM_BACKGROUND = 10000b
EVM_MOUSE = 100000b
EVM_IPC = 1000000b
EVM_STACK = 10000000b