cmm_apps/browser/show_src.h

enum { TAG=1, VALUE, TEXT, COMMENT, SCRIPT};

int opened_font_counter;
int mode;

dword source_buf_start, source_buf_end, source_buf_cap;

// a single input byte expands up to ~30 bytes of markup: grow the buffer instead of
// guessing its size. Every piece written at once is shorter than 256 bytes.
void SourceBufReserve()
{
	dword used = source_buf_end - source_buf_start;
	dword room = source_buf_cap - used;
	IF (room > 256) RETURN;
	source_buf_cap += source_buf_cap;
	source_buf_start = realloc(source_buf_start, source_buf_cap);
	source_buf_end = source_buf_start + used;
}

void SourceBufAdd(dword _mode, src)
{
	IF (_mode) mode = _mode;

	SourceBufReserve();
	strcpy(source_buf_end, src);
	source_buf_end += strlen(source_buf_end);

	IF (strstr(src, "</font>")) opened_font_counter--;
	IF (strstr(src, "<font ")) opened_font_counter++;
}

void CloseAllOpenedFonts(dword _mode)
{
	WHILE (opened_font_counter) SourceBufAdd(_mode, "</font>");
}

void ShowSource(dword _bufdata, _in_bufsize)
{
	dword i;
	bool activate_script_mode = false;

	opened_font_counter=0;
	mode = TEXT;
	source_buf_cap = _in_bufsize * 2;
	source_buf_cap += 4096;
	source_buf_start = malloc(source_buf_cap);
	source_buf_end = source_buf_start;

	SourceBufAdd(TEXT, "<html><head><title>View Source</title></head><body><pre>");

	for (i=_bufdata; i<_bufdata+_in_bufsize; i++) switch (DSBYTE[i])
	{
		CASE '<':
			IF (!strncmp(i+1,"!--", 3)) SourceBufAdd(COMMENT, "<font color=#bbb>&lt;");
			else IF (SCRIPT == mode) {
				IF (!strncmp(i+1,"/script>", 8)) {
					CloseAllOpenedFonts(NULL);
					SourceBufAdd(TAG, "<font color=#00f>&lt;");
				}
				ELSE SourceBufAdd(NULL, "&lt;");
			}
			ELSE IF (COMMENT == mode) {
				SourceBufAdd(NULL, "&lt;");
			}
			ELSE IF (TEXT == mode) {
				IF (!strncmp(i+1,"script", 6)) activate_script_mode = true;
				SourceBufAdd(TAG, "<font color=#00f>&lt;");
			}
			break;
		case '>':
			IF (TAG == mode) && (activate_script_mode) {
				activate_script_mode = false;
				SourceBufAdd(SCRIPT, "&gt;</font><font color=#994500>");
			}
			ELSE IF (VALUE == mode) CloseAllOpenedFonts(TEXT);
			ELSE IF (COMMENT == mode) && (!strncmp(i-2,"--", 2)) {
				SourceBufAdd(TEXT, "&gt;");
				CloseAllOpenedFonts(TEXT);
			}
			ELSE IF (COMMENT == mode) || (SCRIPT == mode) SourceBufAdd(NULL, "&gt;");
			ELSE IF (TAG == mode) SourceBufAdd(TEXT, "&gt;</font>");
			BREAK;
		case '&':
			SourceBufAdd(NULL, "&amp;");
			BREAK;
		case '\"':
		case '\'':
			IF (TAG == mode) SourceBufAdd(VALUE, "<font color=#F301F2>&quot;");
			ELSE IF (VALUE == mode) SourceBufAdd(TAG, "&quot;</font>");
			ELSE SourceBufAdd(NULL, "&quot;");
			BREAK;
		default:
			SourceBufReserve();
			DSBYTE[source_buf_end] = DSBYTE[i];
			source_buf_end++;
	}
	DSBYTE[source_buf_end] = 0;
	LoadInternalPage(source_buf_start, source_buf_end-source_buf_start);
	free(source_buf_start);
}