kolibrios-fun/programs/fs/Eolite/trunk/Eolite.c--

//Leency & Veliant -=- KolibriOS Team -=- 2012
//GNU GPL licence.

//<2F><><EFBFBD><EFBFBD><EFBFBD><EFBFBD><EFBFBD><EFBFBD><EFBFBD><EFBFBD> <20><><EFBFBD><EFBFBD><EFBFBD> <20><><EFBFBD><EFBFBD><EFBFBD>
//IF (strcmp(#path+strlen(#path)-1,"/")<>0) copystr("/",#path+strlen(#path)); //<2F><><EFBFBD><EFBFBD> <20><><EFBFBD>, + "/" <20><><EFBFBD><EFBFBD><EFBFBD><EFBFBD><EFBFBD><EFBFBD><EFBFBD><EFBFBD> <20><><EFBFBD><EFBFBD><EFBFBD><EFBFBD><EFBFBD>
//<2F><><EFBFBD><EFBFBD><EFBFBD><EFBFBD> <20><><EFBFBD><EFBFBD><EFBFBD><EFBFBD><EFBFBD><EFBFBD><EFBFBD><EFBFBD><EFBFBD><EFBFBD><EFBFBD> <20><><EFBFBD><EFBFBD><EFBFBD> <20><><EFBFBD><EFBFBD><EFBFBD><EFBFBD> <20><><EFBFBD> <20><><EFBFBD><EFBFBD><EFBFBD><EFBFBD><EFBFBD><EFBFBD><EFBFBD><EFBFBD> <20><><EFBFBD><EFBFBD><EFBFBD><EFBFBD><EFBFBD><EFBFBD><EFBFBD> <20> <20><><EFBFBD><EFBFBD><EFBFBD> <20> <20><><EFBFBD><EFBFBD><EFBFBD><EFBFBD><EFBFBD><EFBFBD>.

#include "lib\kolibri.h"
#include "lib\memory.h"
#include "lib\edit_box_lib.h"
#include "lib\file_system.h"
#include "imgs\toolbar.txt"
#include "imgs\left_p.txt"

int BUTTON_HEIGHT=18;

//for OpenDir
#define ONLY_SHOW	0
#define WITH_REDRAW	1
#define ONLY_OPEN	2

//<2F><><EFBFBD><EFBFBD><EFBFBD><EFBFBD><EFBFBD><EFBFBD><EFBFBD><EFBFBD>
#define title "Eolite File Manager v1.41"
dword selection_col = 0x94AECE;
dword lpanel_col = 0x00699C;


/*
int  
     f_count,
     f_first,
     f_current;
*/

int  f_visible,
     count,
     za_kadrom,
     curbtn;
	 
	 
byte cut_active,
     rename_active,
     del_active;
byte show_actions=1,
	 show_dev_name=1,
     sort_num=2,
     isdir;
unsigned char
	path[4096],
	edit_path[4096],
	file_path[4096],
	file_name[4096],
	copy_file[4096],
	temp[4096];
int scroll_size;



int toolbar_buttons_x[6]={9,46,85,134,167,203};
char tmp_disk_del_param[]="d0";

dword file_mas[6898];
int j, i, mouse_dd;

struct path_string {
char Item[4096];
};


dword stak[100]; //<2F><><EFBFBD><EFBFBD> About 

edit_box edit1= {250,247,13,0xffffff,0x94AECE,0xD3DDEB,0xffffff,0,248,#edit_path,#mouse_dd,64,6,6};
edit_box edit2= {250,213,80,0xFFFFCC,0x94AECE,0xFFFFCC,0xffffff,0,248,#file_name,#mouse_dd,64,6,6};

proc_info Form;
dword buf, off; //<2F><><EFBFBD> <20><><EFBFBD><EFBFBD><EFBFBD><EFBFBD> <20> <20><><EFBFBD><EFBFBD><EFBFBD><EFBFBD>

#include "include\about_dialog.h"
#include "include\some_code.h"
#include "include\sorting.h"
#include "include\icons_f.h"
#include "include\ini.h"
#include "include\left_panel.h"
#include "include\history.h"

void main() 
{
	word key, id; 
	mouse m;
	int scroll_used;

	load_editbox_lib();
	GetSystemDiscs();
	GetIni(1);
	
	edit1.shift_color=selection_col;
	edit2.shift_color=selection_col;
	
	if (param)
	{
		copystr(#param, #path);
		if (strcmp(#path+strlen(#path)-1,"/")<>0) copystr("/",#path+strlen(#path)); //<2F><><EFBFBD><EFBFBD> <20><><EFBFBD>, + "/"
	}
	else
		copystr("/rd/1/", #path);
		
	Open_Dir(#path,ONLY_OPEN);
	loop()	switch(WaitEvent())
	{
		case evMouse:
				IF (del_active) break;
				
				id=GetSlot(Form.ID); 
				IF (id<>ActiveProcess()) break; //<2F><><EFBFBD><EFBFBD> <20><><EFBFBD><EFBFBD> <20><> <20><><EFBFBD><EFBFBD><EFBFBD><EFBFBD><EFBFBD> <20><> <20><><EFBFBD><EFBFBD><EFBFBD><EFBFBD><EFBFBD> <20><><EFBFBD><EFBFBD> <20><> <20><><EFBFBD><EFBFBD><EFBFBD><EFBFBD><EFBFBD><EFBFBD><EFBFBD>
				
				IF (!rename_active) edit_box_mouse stdcall(#edit1); ELSE edit_box_mouse stdcall(#edit2);
				
				m.get();

				if (m.x>=Form.width-26) && (m.x<=Form.width-6) && (m.y>40) && (m.y<57)
				{
					IF (m.lkm==1) DrawRegion_3D(onLeft(26,0),41,14,14,0xC7C7C7,0xFFFFFF);
					WHILE (m.lkm==1) && (za_kadrom>0)
					{
						Pause(10);
						za_kadrom--;
						List_ReDraw();
						m.get();
					}
					DrawRegion_3D(onLeft(26,0),41,14,14,0xFFFFFF,0xC7C7C7);
				}

				if (m.x>=Form.width-26) && (m.x<=Form.width-6) && (m.y>onTop(22,0)+1) && (m.y<onTop(22,0)+16)
				{
					IF (m.lkm==1) DrawRegion_3D(onLeft(26,0),onTop(21,0),14,14,0xC7C7C7,0xFFFFFF);
					while (m.lkm==1) && (za_kadrom<count-f_visible)
					{
						Pause(10);
						za_kadrom++;
						List_ReDraw();
						m.get();
					}
					DrawRegion_3D(onLeft(26,0),onTop(21,0),14,14,0xFFFFFF,0xC7C7C7);
				}

				//<2F><><EFBFBD><EFBFBD><EFBFBD><EFBFBD><EFBFBD><EFBFBD> <20><><EFBFBD><EFBFBD>
				IF (m.vert==65535) && (za_kadrom>0)
				{
					if (za_kadrom>0) za_kadrom--;
					if (curbtn<f_visible-1) curbtn++;
					List_ReDraw();
					if (za_kadrom>0) za_kadrom--;
					if (curbtn<f_visible-1) curbtn++;
					List_ReDraw();
				}
				IF (m.vert==1) && (za_kadrom<count-f_visible)
				{
					if (za_kadrom<count-f_visible) za_kadrom++;
					if (curbtn>0) curbtn--;
					List_ReDraw();
					if (za_kadrom<count-f_visible) za_kadrom++;
					if (curbtn>0) curbtn--;
					List_ReDraw();
				}
				//<2F><><EFBFBD><EFBFBD><EFBFBD><EFBFBD>
				if (!m.lkm) scroll_used=NULL;
				if (m.x>=Form.width-26) && (m.x<=Form.width-6) && (m.y>56) && (m.y<Form.height) && (m.lkm) scroll_used=1;
				
				if (scroll_used)
				{
					IF (scroll_size/2+57>m.y) || (m.y<0) || (m.y>4000) m.y=scroll_size/2+57; //<2F><><EFBFBD><EFBFBD> <20><><EFBFBD><EFBFBD><EFBFBD><EFBFBD> <20><><EFBFBD> <20><><EFBFBD><EFBFBD><EFBFBD>
					id=za_kadrom; //<2F><><EFBFBD><EFBFBD><EFBFBD><EFBFBD><EFBFBD><EFBFBD><EFBFBD> <20><><EFBFBD><EFBFBD><EFBFBD><EFBFBD> <20><><EFBFBD><EFBFBD><EFBFBD><EFBFBD><EFBFBD><EFBFBD><EFBFBD><EFBFBD>
					j= scroll_size/2;
					za_kadrom = m.y -j -57 * count;
					za_kadrom /= onTop(22,57);
					IF (f_visible+za_kadrom>count) za_kadrom=count-f_visible;
					IF (id<>za_kadrom) List_ReDraw(); //<2F><><EFBFBD><EFBFBD> <20><><EFBFBD><EFBFBD><EFBFBD><EFBFBD> <20><><EFBFBD> <20><> <20><><EFBFBD><EFBFBD><EFBFBD><EFBFBD><EFBFBD><EFBFBD><EFBFBD><EFBFBD><EFBFBD><EFBFBD><EFBFBD><EFBFBD>
				}
				break;  
//Button pressed-----------------------------------------------------------------------------
		case evButton:
				id=GetButtonID();
				IF (id==1) ExitProcess();

				IF (del_active)
				{
					IF (id==301) || (id==302) Del_File(302-id);
					break;
				}
				switch(id) 
				{
					case 21: //Back
							GoBack();
							break;
					case 22: //Forward
							if (HistoryPath(GO_FORWARD))
							{
								za_kadrom=curbtn=NULL; //<2F><><EFBFBD><EFBFBD><EFBFBD> <20><><EFBFBD><EFBFBD><EFBFBD><EFBFBD>
								Open_Dir(#path,WITH_REDRAW);
							}
							break;
					case 23: //up!
							Dir_Up();
							break;
					case 24: //cut
							key=24; 
					case 25: //copy
							goto CTRLC_MARK;
					case 26: //paste
							Paste();
							break;
					case 27: //goto edit_path
							Goto_edit_path();
							break; 
					case 31...33: //sort
							IF(sort_num==1) DrawBar(onLeft(192,168)/2+210,45,6,9,0xE4DFE1);
							IF(sort_num==2) DrawBar(onLeft(115,0),45,6,9,0xE4DFE1);
							IF(sort_num==3) DrawBar(onLeft(44,0),45,6,9,0xE4DFE1);
							sort_num=id-30;
							Open_Dir(#path,1);
							break; 
					case 30: //about
							CreateThread(#about_dialog,#stak); 
							break;
					case 77:
							IF (show_actions==1) show_actions=0; ELSE show_actions=1;
							Actions();
							break;
					case 78: //rescan devices
							Tip(56, "Devices", 78, "-");
							Pause(10);
							GetSystemDiscs();
							Open_Dir(#path,WITH_REDRAW);
							DrawLeftPanel();
							break;
					case 80: //rename
							goto REN_MARK; 
					case 81: //Delete file
							Del_Form();
							break;
					case 82: //create folder
						NEW_FOLDER_MARK:
							copystr(#path, #temp);
							copystr("New folder", #temp+strlen(#temp));
							CreateFolder(#temp);
							IF (!EAX){
								SelectFile("New folder");
								goto REN_MARK;
							}
							ELSE
							{
								Write_Error(EAX);
								ShowMessage("Folder can not be created.");
							}
							break;
					case 100...120:
						DEVICE_MARK:
							DrawRegion_3D(17,id-100*16+74,159,16, 0, 0); //<2F><><EFBFBD><EFBFBD><EFBFBD><EFBFBD><EFBFBD><EFBFBD><EFBFBD>
							copystr(#disk_list[id-100].Item, #path);
							za_kadrom=curbtn=0;
							Open_Dir(#path,1);
							Pause(5);
							DrawRegion_3D(17,id-100*16+74,159,16, 0xFFFFFF, 0xFFFFFF);
							break;
					case 130...160:
							tmp_disk_del_param[1]=disk_list[id-130].Item[4];
							RunProgram("/sys/tmpdisk", #tmp_disk_del_param);
							Pause(10);
							GetSystemDiscs();
							Open_Dir(#path,WITH_REDRAW);
							DrawLeftPanel();
							break;
					default:
							if (id<200) break; //<2F><><EFBFBD><EFBFBD><EFBFBD><EFBFBD> <20><> <20><><EFBFBD><EFBFBD><EFBFBD><EFBFBD> <20><><EFBFBD><EFBFBD><EFBFBD><EFBFBD>
							if (curbtn!=id-201)	{FileList_ReDraw(id-201-curbtn); break;}
							else
						OPEN_MARK:
							if (!isdir) GetIni(0); else
							if (!strcmp(#file_name,"..")) Dir_Up();
							else
							{
						OPEN_DEV:
									copystr(#file_path, #path);
									IF (strcmp(#path+strlen(#path)-1,"/")<>0) copystr("/",#path+strlen(#path)); //<2F><><EFBFBD><EFBFBD> <20><><EFBFBD>, + "/"
									za_kadrom=curbtn=0;
									Open_Dir(#path,1);
							}
				}
				break;
//Key pressed-----------------------------------------------------------------------------
		case evKey:
			key = GetKey();
			if (Form.status_window>2) break;
			IF (del_active)
			{
				IF (key==013) Del_File(true);
				IF (key==027) Del_File(false);
				break;
			}
			IF (edit1.flags<>64) && (edit1.flags<>0) && (key<>13)
			{
				EAX=key<<8;
				edit_box_key stdcall (#edit1);
				break;
			} 
			IF (edit2.flags<>64) && (key<>13) && (key<>27)
			{
				EAX=key<<8;
				edit_box_key stdcall (#edit2);
				break;
			}
			switch (key)
			{
					case 209...217:
							id=key-110;
							IF (id-100>=disc_num) break;
							GOTO DEVICE_MARK;
					case   8: //<2F><><EFBFBD><EFBFBD><EFBFBD>
							//GoBack();
							Dir_Up();
							break; 
					case 004: //Ctrl+D <20><><EFBFBD> <20><> <20><><EFBFBD> <20><><EFBFBD><EFBFBD> <20><><EFBFBD><EFBFBD><EFBFBD><EFBFBD><EFBFBD><EFBFBD><EFBFBD>
							copystr("\\S__", #temp);
							copystr(#file_path, #temp+strlen(#temp));
							RunProgram("/sys/media/kiv", #temp);
							break;
					case 014: //Ctrl+N <20><><EFBFBD><EFBFBD><EFBFBD> <20><><EFBFBD><EFBFBD>
							IF (Form.left==98) MoveSize(Form.left-20,Form.top-20,OLD,OLD);
							RunProgram("/sys/File Managers/Eolite", #path);
							break; 
					case 024: //Ctrl+X
					case 003: //Ctrl+C
							CTRLC_MARK:
							IF (isdir) break; //<2F><><EFBFBD><EFBFBD><EFBFBD> <20><><EFBFBD><EFBFBD> <20><><EFBFBD> <20><><EFBFBD><EFBFBD><EFBFBD><EFBFBD><EFBFBD><EFBFBD><EFBFBD><EFBFBD> <20><> <20><><EFBFBD><EFBFBD><EFBFBD>
							copystr(#file_path,#copy_file); //<2F><><EFBFBD><EFBFBD><EFBFBD><EFBFBD><EFBFBD><EFBFBD><EFBFBD> <20><><EFBFBD><EFBFBD><EFBFBD> <20><><EFBFBD><EFBFBD> <20><><EFBFBD><EFBFBD><EFBFBD><EFBFBD><EFBFBD><EFBFBD><EFBFBD><EFBFBD>
							IF (key==24) cut_active=1; ELSE cut_active=0; 
							break;
					case 022: //Ctrl+V
							Paste();
							break;
					case 027: //Esc
							IF (rename_active==1) ReName(false);
							break;
					case 013: //Enter
							IF (rename_active==1) {ReName(true); break;}
							IF (strcmp(#path,#edit_path)<>0) Goto_edit_path();
							ELSE GOTO OPEN_MARK;
							break; 
					case 55: //F6 - new folder
							goto NEW_FOLDER_MARK;
					case 56:  //IF (rename_active==1) break;//up
					case 178: //up
							FileList_ReDraw(-1);
							break;
					case 177: //down
							FileList_ReDraw(1);
							break;
					case 180: //home
							za_kadrom=0;
							curbtn=0;
							List_ReDraw();
							break;
					case 181: //end
							za_kadrom=count-f_visible;
							curbtn=f_visible-1;
							List_ReDraw();
							break;
					case 183: //Page Down
							FileList_ReDraw(f_visible-1);
							break;
					case 184: //Page Up
							FileList_ReDraw(-f_visible+1);
							break;
					case 051: //<2F><><EFBFBD><EFBFBD><EFBFBD><EFBFBD> F2
							REN_MARK:
							DeleteButton(curbtn+201); //<2F><><EFBFBD> <20><><EFBFBD><EFBFBD> <20><><EFBFBD><EFBFBD><EFBFBD> <20><><EFBFBD><EFBFBD> <20><><EFBFBD><EFBFBD><EFBFBD><EFBFBD><EFBFBD><EFBFBD> <20><><EFBFBD><EFBFBD><EFBFBD>
							edit2.flags=66; //<2F><><EFBFBD><EFBFBD><EFBFBD><EFBFBD> <20><><EFBFBD><EFBFBD><EFBFBD><EFBFBD><EFBFBD><EFBFBD><EFBFBD> <20><><EFBFBD><EFBFBD><EFBFBD><EFBFBD><EFBFBD><EFBFBD>
							edit2.width=onLeft(24,217);
							edit2.top=curbtn*BUTTON_HEIGHT+59;
							edit2.size=edit2.pos=strlen(#file_name);
							edit_box_draw  stdcall (#edit2);
							DrawBar(213,curbtn*BUTTON_HEIGHT+58,edit2.width+1,1,0xFFFFCC); //<2F><><EFBFBD><EFBFBD><EFBFBD><EFBFBD> <20><><EFBFBD><EFBFBD><EFBFBD><EFBFBD> <20><><EFBFBD><EFBFBD><EFBFBD><EFBFBD> <20><><EFBFBD> <20><><EFBFBD><EFBFBD><EFBFBD><EFBFBD><EFBFBD><EFBFBD><EFBFBD><EFBFBD><EFBFBD><EFBFBD>
							rename_active=1;
							break;
					case 052: //<2F><><EFBFBD><EFBFBD><EFBFBD><EFBFBD> F3
							IF (isdir==false) RunProgram("/sys/tinypad", #file_path);
							break;
					case 053: //<2F><><EFBFBD><EFBFBD><EFBFBD><EFBFBD> F4
							IF (isdir==false) RunProgram("/sys/develop/heed", #file_path);
							break;
					case 054: //F5
							Open_Dir(#path,1);
							break;
					case 182: //delete file
							Del_Form();
							break; 
					default:    
							for (i=curbtn+za_kadrom+1; i<count; i++)
							{
								copystr(file_mas[i]*304+buf+72,#temp);
								AL=DSBYTE[#temp]; 
								IF(AL>='A')&&(AL<='Z')DSBYTE[#temp]=AL|0x20;
								IF (temp[0]==key)
								{
									FileList_ReDraw(i-curbtn-za_kadrom);
									break;
								}
							}
			}                         
			BREAK;
		case evReDraw:
			draw_window();
	}
}


inline fastcall void draw_window()
{	
	int min_size_y = disc_num*16+195;
	
	if (GetScreenHeight()<480)
		DefineAndDrawWindow(20,0,582,GetScreenHeight()-30,0x73,0xE4DFE1,title);
	else
		DefineAndDrawWindow(98,90,582,482,0x73,0xE4DFE1,title);
	Form.GetInfo(#Form, SelfInfo);
	if (Form.status_window>2) return; //<2F><><EFBFBD><EFBFBD><EFBFBD><EFBFBD> <20><> <20><><EFBFBD><EFBFBD><EFBFBD><EFBFBD> <20><><EFBFBD><EFBFBD> <20><><EFBFBD><EFBFBD> <20><><EFBFBD><EFBFBD><EFBFBD><EFBFBD><EFBFBD><EFBFBD><EFBFBD> <20> <20><><EFBFBD><EFBFBD><EFBFBD><EFBFBD><EFBFBD><EFBFBD><EFBFBD>
	if (Form.height<min_size_y) MoveSize(OLD,OLD,OLD,min_size_y);
	if (Form.width<480) MoveSize(OLD,OLD,480,OLD);
	  
	//toolbar buttons
	PutPaletteImage(#toolbar,246,39,0,0,#toolbar_pal);
	for (j=0; j<3; j++) DefineButton(toolbar_buttons_x[j]+2,5+2,31-5,29-5,21+j+BT_HIDE,0xE4DFE1);
	for (j=3; j<6; j++) DefineButton(toolbar_buttons_x[j],5,31,29,21+j+BT_HIDE,0xE4DFE1);
	//<2F><><EFBFBD><EFBFBD><EFBFBD><EFBFBD> <20><><EFBFBD><EFBFBD><EFBFBD><EFBFBD>
	edit1.width=Form.width-314;
	DrawBar(246,0,onLeft(246,60),12,0xE4DFE1); //<2F><><EFBFBD> <20><><EFBFBD> <20><><EFBFBD><EFBFBD><EFBFBD><EFBFBD><EFBFBD> <20><><EFBFBD><EFBFBD><EFBFBD><EFBFBD>
	DrawBar(246,29,onLeft(246,60),10,0xE4DFE1); //<2F><><EFBFBD> <20><><EFBFBD> <20><><EFBFBD><EFBFBD><EFBFBD><EFBFBD><EFBFBD> <20><><EFBFBD><EFBFBD><EFBFBD><EFBFBD>
	DrawRegion_3D(246,12,onLeft(66,246),16,0x94AECE,0x94AECE);	//<2F><><EFBFBD><EFBFBD><EFBFBD><EFBFBD>
	DefineButton(onLeft(34,0),6,27,28,30+BT_HIDE+BT_NOFRAME,0xE4DFE1); //about
	DefineButton(onLeft(66,0),12,18,16,27+BT_HIDE,0xE4DFE1); //<2F><><EFBFBD><EFBFBD><EFBFBD><EFBFBD> <20><><EFBFBD><EFBFBD><EFBFBD><EFBFBD><EFBFBD><EFBFBD>
	PutPaletteImage(#goto_about,56,40,Form.width-65,0,#goto_about_pal);
	//<2F><><EFBFBD><EFBFBD><EFBFBD><EFBFBD><EFBFBD><EFBFBD><EFBFBD><EFBFBD><EFBFBD><EFBFBD><EFBFBD><EFBFBD> <20><><EFBFBD><EFBFBD><EFBFBD><EFBFBD>
	DrawRegion_3D(1,40,Form.width-12,onTop(46,0),0x94AECE,0x94AECE); //<2F><><EFBFBD><EFBFBD><EFBFBD> <20><><EFBFBD><EFBFBD><EFBFBD><EFBFBD>
	DrawRegion_3D(0,39,Form.width-10,onTop(44,0),0xE4DFE1,0xE4DFE1); //<2F><><EFBFBD>
	DrawLeftPanel();
	//SortButtons
	DrawFlatButton(192,40,onLeft(192,168),16,31,0xE4DFE1,"File");
	DrawFlatButton(onLeft(168,0),40,73,16,32,0xE4DFE1,"Type");
	DrawFlatButton(onLeft(95,0),40,68,16,33,0xE4DFE1,"Size");
	//<2F><><EFBFBD><EFBFBD><EFBFBD><EFBFBD><EFBFBD><EFBFBD><EFBFBD><EFBFBD><EFBFBD><EFBFBD><EFBFBD><EFBFBD> <20><><EFBFBD><EFBFBD><EFBFBD><EFBFBD>
	Open_Dir(#path,ONLY_SHOW);
	//<2F><><EFBFBD><EFBFBD><EFBFBD><EFBFBD><EFBFBD><EFBFBD><EFBFBD>
	DrawBar(onLeft(27,0),57,1,onTop(22,57),0x94AECE); //<2F><><EFBFBD><EFBFBD><EFBFBD> <20><><EFBFBD><EFBFBD><EFBFBD> <20><> <20><><EFBFBD><EFBFBD><EFBFBD><EFBFBD><EFBFBD><EFBFBD><EFBFBD> 
	DrawFlatButton(onLeft(27,0),40,16,16,0,0xE4DFE1,"\x18");		//<2F><><EFBFBD><EFBFBD><EFBFBD><EFBFBD><EFBFBD><EFBFBD><EFBFBD> <20><><EFBFBD><EFBFBD><EFBFBD>
	DrawFlatButton(onLeft(27,0),onTop(22,0),16,16,0,0xE4DFE1,"\x19");//<2F><><EFBFBD><EFBFBD><EFBFBD><EFBFBD><EFBFBD><EFBFBD><EFBFBD> <20><><EFBFBD><EFBFBD>
	if (del_active) Del_Form();
}


void KEdit()
{
	edit1.size=edit1.pos=strlen(#edit_path);
	edit1.offset=0;
	edit_box_draw  stdcall (#edit1);
}


void FileList_ReDraw(int curbtn_)
{
	if (curbtn_<=0) //<2F><><EFBFBD><EFBFBD><EFBFBD>
	{
		IF (za_kadrom==0) && (curbtn<=0) return;
		IF (-curbtn_-1<curbtn)
		{
			Line_ReDraw(0xFFFFFF, curbtn); //<2F><><EFBFBD><EFBFBD><EFBFBD> <20><><EFBFBD><EFBFBD><EFBFBD><EFBFBD>
			curbtn+=curbtn_;
			Line_ReDraw(selection_col, curbtn); //<2F><><EFBFBD><EFBFBD><EFBFBD><EFBFBD><EFBFBD><EFBFBD><EFBFBD>
			return;
		}
		ELSE
		{
			IF (-curbtn_<za_kadrom) za_kadrom+=curbtn_; ELSE za_kadrom=0;
			curbtn=0;
			List_ReDraw();
			return;
		}
	}
	else  //<2F><><EFBFBD><EFBFBD>
	{
		IF (za_kadrom==count-f_visible) && (curbtn==f_visible-1) return;
		IF (f_visible-curbtn>curbtn_)
		{
			Line_ReDraw(0xFFFFFF, curbtn); //<2F><><EFBFBD><EFBFBD><EFBFBD> <20><><EFBFBD><EFBFBD><EFBFBD><EFBFBD>
			curbtn+=curbtn_;
			Line_ReDraw(selection_col, curbtn); //<2F><><EFBFBD><EFBFBD><EFBFBD><EFBFBD><EFBFBD><EFBFBD><EFBFBD>
			return;
		}
		else
		{
			IF(za_kadrom+curbtn+curbtn_>=count)
			{
				za_kadrom=count-f_visible;
				curbtn=curbtn_-za_kadrom+curbtn;
				}
			ELSE
			{
				za_kadrom+=curbtn_+curbtn-f_visible+1;
				curbtn=f_visible-1;
			}
			
			IF (curbtn<0) || (curbtn>f_visible)
			{
				curbtn=f_visible-1;
			}
			List_ReDraw();
		}
	}
}




void List_ReDraw()
{
	int paint_x=f_visible*BUTTON_HEIGHT+57;
	IF (count-za_kadrom<f_visible) || (curbtn>f_visible-1) //<2F><><EFBFBD><EFBFBD> <20><> <20> <20><><EFBFBD><EFBFBD><EFBFBD> <20><><EFBFBD><EFBFBD><EFBFBD><EFBFBD> <20><><EFBFBD><EFBFBD><EFBFBD><EFBFBD> <20><><EFBFBD><EFBFBD><EFBFBD><EFBFBD><EFBFBD><EFBFBD><EFBFBD> <20><><EFBFBD><EFBFBD> <20><><EFBFBD><EFBFBD><EFBFBD><EFBFBD><EFBFBD><EFBFBD><EFBFBD> <20><><EFBFBD><EFBFBD><EFBFBD><EFBFBD> <20><><EFBFBD><EFBFBD><EFBFBD> <20><><EFBFBD><EFBFBD><EFBFBD><EFBFBD>
	{ za_kadrom=count-f_visible; curbtn=f_visible-1; } //<2F><><EFBFBD> <20><><EFBFBD><EFBFBD> <20><><EFBFBD><EFBFBD><EFBFBD><EFBFBD><EFBFBD><EFBFBD><EFBFBD> <20><><EFBFBD><EFBFBD><EFBFBD> <20><><EFBFBD><EFBFBD><EFBFBD><EFBFBD><EFBFBD><EFBFBD><EFBFBD><EFBFBD><EFBFBD> <20><><EFBFBD><EFBFBD> <20><> <20><><EFBFBD><EFBFBD><EFBFBD><EFBFBD>

	FOR (j=0; j<f_visible; j++) IF (curbtn<>j) Line_ReDraw(0xFFFFFF, j); ELSE Line_ReDraw(selection_col, curbtn);
		DrawBar(192,paint_x,onLeft(27,192),onTop(paint_x,6),0xFFFFFF); //<2F><><EFBFBD><EFBFBD><EFBFBD><EFBFBD><EFBFBD> <20><><EFBFBD><EFBFBD><EFBFBD> <20><><EFBFBD><EFBFBD><EFBFBD><EFBFBD><EFBFBD>
		DrawBar(onLeft(168,0),paint_x,1,onTop(paint_x,6),0xE4DFE1); //<2F><><EFBFBD><EFBFBD><EFBFBD><EFBFBD> <20><><EFBFBD><EFBFBD><EFBFBD> <20><><EFBFBD><EFBFBD><EFBFBD><EFBFBD><EFBFBD><EFBFBD><EFBFBD><EFBFBD><EFBFBD><EFBFBD> 1
		DrawBar(onLeft(95,0),paint_x,1,onTop(paint_x,6),0xE4DFE1); //<2F><><EFBFBD><EFBFBD><EFBFBD><EFBFBD> <20><><EFBFBD><EFBFBD><EFBFBD> <20><><EFBFBD><EFBFBD><EFBFBD><EFBFBD><EFBFBD><EFBFBD><EFBFBD><EFBFBD><EFBFBD><EFBFBD> 2
	TVScroll();
}


void Line_ReDraw(dword color, filenum){
	dword text_col=0, name_len,
	y=filenum*BUTTON_HEIGHT+57; //<2F><><EFBFBD><EFBFBD><EFBFBD><EFBFBD><EFBFBD><EFBFBD><EFBFBD> <20><><EFBFBD><EFBFBD><EFBFBD><EFBFBD> <20><> Y
	IF (rename_active==1) ReName(false);
	DefineButton(192,y,onLeft(28,192),BUTTON_HEIGHT,201+filenum+BT_HIDE+BT_NOFRAME,color); //<2F><><EFBFBD><EFBFBD><EFBFBD>
	//<2F><>, <20> <20><> <20><><EFBFBD><EFBFBD><EFBFBD> <20><><EFBFBD> <20><><EFBFBD><EFBFBD><EFBFBD><EFBFBD>, <20><> <20><><EFBFBD><EFBFBD> <20><><EFBFBD><EFBFBD><EFBFBD><EFBFBD><EFBFBD><EFBFBD><EFBFBD><EFBFBD><EFBFBD> <20><> <20><><EFBFBD><EFBFBD><EFBFBD>
	DrawBar(192,y,3,BUTTON_HEIGHT,color); 
	DrawBar(192+19,y,onLeft(46,192),BUTTON_HEIGHT,color); DrawBar(195,y+17,16,1,color);
	if (BUTTON_HEIGHT>18) DrawBar(195,y+18,16,BUTTON_HEIGHT-18,color);
	if (BUTTON_HEIGHT>15) DrawBar(195,y,16,BUTTON_HEIGHT-15,color); 

	off=file_mas[filenum+za_kadrom]*304 + buf+72;

	if (!TestBit(ESDWORD[off-40], 4)) //<2F><><EFBFBD> <20><><EFBFBD><EFBFBD> <20><><EFBFBD> <20><><EFBFBD><EFBFBD><EFBFBD>?
	{	
		copystr(off,#temp);
		Put_icon(#temp+strchr(#temp,'.'), BUTTON_HEIGHT/2-7+y, color);
		WriteText(7-strlen(ConvertSize(ESDWORD[off-8]))*6+onLeft(75,0),BUTTON_HEIGHT-6/2+y,0x80,0,ConvertSize(ESDWORD[off-8]),0); //size
	}
	else
		if (!strcmp("..",off))
			Put_icon("..", BUTTON_HEIGHT/2-7+y, color);
		else
			Put_icon("<DIR>", BUTTON_HEIGHT/2-7+y, color);

	if (TestBit(ESDWORD[off-40],1)) || (TestBit(ESDWORD[off-40],2)) text_col=0xA6A6B7; //<2F><><EFBFBD><EFBFBD> <20><><EFBFBD><EFBFBD><EFBFBD><EFBFBD><EFBFBD> <20><><EFBFBD> <20><><EFBFBD><EFBFBD><EFBFBD><EFBFBD><EFBFBD><EFBFBD><EFBFBD>?

	if (color<>0xFFFfff)
	{
		isdir=TestBit(ESDWORD[off-40], 4);
		
		copystr(off,#file_name);
		copystr(#path,#file_path);
		copystr(#file_name,#file_path+strlen(#file_path)); //<2F><><EFBFBD><EFBFBD><EFBFBD><EFBFBD> <20><><EFBFBD><EFBFBD> <20> <20><><EFBFBD><EFBFBD><EFBFBD>
		IF (text_col==0xA6A6B7) text_col=0xFFFFFF;
	}
	name_len = onLeft(215,165)/6;
	IF (strlen(off)<name_len) name_len = strlen(off);  //<2F><><EFBFBD><EFBFBD><EFBFBD><EFBFBD> <20><><EFBFBD><EFBFBD><EFBFBD><EFBFBD><EFBFBD><EFBFBD> <20><><EFBFBD><EFBFBD><EFBFBD>
	WriteText(215,BUTTON_HEIGHT-6/2+y,0,text_col,off,name_len);  //<2F><><EFBFBD> <20><><EFBFBD><EFBFBD><EFBFBD>
	DrawBar(onLeft(168,0),y,1,BUTTON_HEIGHT,0xE4DFE1); //<2F><><EFBFBD><EFBFBD><EFBFBD><EFBFBD> <20><><EFBFBD><EFBFBD><EFBFBD> <20><><EFBFBD><EFBFBD><EFBFBD><EFBFBD><EFBFBD><EFBFBD><EFBFBD><EFBFBD><EFBFBD><EFBFBD> 1
	DrawBar(onLeft(95,0),y,1,BUTTON_HEIGHT,0xE4DFE1); //<2F><><EFBFBD><EFBFBD><EFBFBD><EFBFBD> <20><><EFBFBD><EFBFBD><EFBFBD> <20><><EFBFBD><EFBFBD><EFBFBD><EFBFBD><EFBFBD><EFBFBD><EFBFBD><EFBFBD><EFBFBD><EFBFBD> 2
}


void Open_Dir(dword temp_, redraw){
	int errornum;
	char path_[4096],
	somelen=strlen(temp_)-1;
	
	//debug("reading directory");
	//debug(temp_);
	if (redraw<>ONLY_SHOW)
	{
		copystr(temp_, #path_);
		if (somelen) path_[somelen]=0x00;
		
		if (buf) free(buf);
    	buf = malloc(32);
		errornum=ReadDir(0, buf, #path_);
		if (errornum<>0) //<2F><><EFBFBD><EFBFBD><EFBFBD><EFBFBD> <20><><EFBFBD> <20><><EFBFBD><EFBFBD><EFBFBD><EFBFBD> <20><><EFBFBD><EFBFBD><EFBFBD>
		{
			HistoryPath(ADD_NEW_PATH);
			GoBack();
			Write_Error(errornum);
			return;
		}
    	count = ESDWORD[buf+8];
    	buf = realloc(count * 304 + 32, buf); //<2F><><EFBFBD><EFBFBD><EFBFBD><EFBFBD> 32?
		ReadDir(count, buf, #path_);
		IF (EBX>6897) && (EBX<>-1) EBX=6897; //1 <20><> <20><><EFBFBD><EFBFBD><EFBFBD> ;)
		count=EBX;
	}
	if (count<>-1)
	{
		//debug("successfully \n");
		copystr(temp_,#edit_path);
		KEdit();
		HistoryPath(ADD_NEW_PATH);
		IF (!strcmp(".",buf+72)) {count--; memmov(buf,buf+304,count*304);} //<2F><><EFBFBD><EFBFBD><EFBFBD><EFBFBD><EFBFBD><EFBFBD><EFBFBD> <20><><EFBFBD><EFBFBD><EFBFBD><EFBFBD><EFBFBD> "."
		FOR (j=0;j<f_visible;j++) DeleteButton(201+j); //<2F><><EFBFBD><EFBFBD><EFBFBD><EFBFBD><EFBFBD> <20><><EFBFBD><EFBFBD><EFBFBD><EFBFBD>
		f_visible=onTop(6,57)/BUTTON_HEIGHT;                                                                                             
		IF (count<f_visible) f_visible=count;
		//<2F><><EFBFBD><EFBFBD><EFBFBD><EFBFBD><EFBFBD><EFBFBD><EFBFBD> <20><><EFBFBD><EFBFBD><EFBFBD><EFBFBD><EFBFBD><EFBFBD><EFBFBD><EFBFBD>
		IF (sort_num==1) WriteText(Form.width+60/2,45,0x80,0x4E78AC,"\x19",0);
		IF (sort_num==2) WriteText(Form.width-115,45,0x80,0x4E78AC,"\x19",0);
		IF (sort_num==3) WriteText(Form.width-44,45,0x80,0x4E78AC,"\x19",0);
		IF (redraw<>ONLY_SHOW) Sorting(); //<2F><><EFBFBD> <20><><EFBFBD><EFBFBD><EFBFBD><EFBFBD><EFBFBD> <20><><EFBFBD><EFBFBD><EFBFBD> <20><><EFBFBD> <20><><EFBFBD><EFBFBD><EFBFBD><EFBFBD><EFBFBD><EFBFBD> <20><><EFBFBD><EFBFBD>
		IF (redraw<>ONLY_OPEN) List_ReDraw();
	}
	IF (count==-1) && (redraw<>ONLY_OPEN) {f_visible=count=0; List_ReDraw();}
}



inline Sorting()
{
	dword k=0, l=1;
	if (!strcmp(#path,"/")) //<2F><> <20><><EFBFBD><EFBFBD><EFBFBD><EFBFBD><EFBFBD><EFBFBD><EFBFBD><EFBFBD><EFBFBD> <20><><EFBFBD><EFBFBD><EFBFBD> <20> <20><> <20><><EFBFBD><EFBFBD><EFBFBD><EFBFBD> <20><><EFBFBD><EFBFBD><EFBFBD><EFBFBD><EFBFBD> <20> "/"
	{
		FOR(k=1;k<count;k++;) file_mas[k]=k;
		return;
	}
	FOR (j=count-1, off=count-1*304+buf+32; j>=0; j--, off-=304;)  //<2F><><EFBFBD><EFBFBD><EFBFBD> <20><><EFBFBD><EFBFBD><EFBFBD>, <20><><EFBFBD><EFBFBD><EFBFBD> <20><><EFBFBD><EFBFBD>
	{
		TitleCase(off+40);
		if (TestBit(ESDWORD[off],4)) //<2F><><EFBFBD><EFBFBD><EFBFBD>?
		{
			file_mas[k]=j;
			k++;
		}
		else
		{
			file_mas[count-l]=j;
			l++;
		}
	}
	//<2F><><EFBFBD><EFBFBD><EFBFBD><EFBFBD><EFBFBD><EFBFBD><EFBFBD><EFBFBD> <20><><EFBFBD><EFBFBD><EFBFBD><EFBFBD><EFBFBD><EFBFBD><EFBFBD><EFBFBD>: <20><><EFBFBD><EFBFBD><EFBFBD><EFBFBD><EFBFBD> <20><><EFBFBD><EFBFBD><EFBFBD>, <20><><EFBFBD><EFBFBD><EFBFBD> <20><><EFBFBD><EFBFBD><EFBFBD>
	Sort_by_Name(0,k-1);
	IF (sort_num==1) Sort_by_Name(k,count-1);
	IF (sort_num==2) Sort_by_Type(k,count-1);
	IF (sort_num==3) Sort_by_Size(k,count-1);
	//<2F><><EFBFBD><EFBFBD> <20><><EFBFBD><EFBFBD><EFBFBD> ".." <20><> <20><><EFBFBD><EFBFBD><EFBFBD><EFBFBD>, <20><><EFBFBD><EFBFBD><EFBFBD><EFBFBD> <20><> <20><><EFBFBD><EFBFBD>
	IF (k>0) && (strcmp(file_mas[0]*304+buf+72,"..")<>0) FOR(k=k-1; k>0; k--;) IF (!strcmp(file_mas[k]*304+buf+72,"..")) file_mas[k]><file_mas[0];
}


void Del_Form()
{
	int dform_x=Form.width/2-13;
	//<2F><><EFBFBD><EFBFBD> <20><><EFBFBD><EFBFBD>
	FOR (i=5;i<11;i++) DeleteButton(201+i); //<2F><><EFBFBD><EFBFBD><EFBFBD><EFBFBD><EFBFBD> <20><><EFBFBD><EFBFBD><EFBFBD><EFBFBD> <20><><EFBFBD> <20><><EFBFBD><EFBFBD><EFBFBD><EFBFBD>
	DrawFlatButton(dform_x,160,200,80,0,0xE4DFE1, ""); //<2F><><EFBFBD><EFBFBD><EFBFBD>
	WriteText(dform_x+19,175,0x80,0,"Do you really want to delete",0);
	IF (strlen(#file_name)<28) 
		{
			WriteText(strlen(#file_name)*6+dform_x+20,190,0x80,0,"?",0);
			WriteText(dform_x+20,190,0x80,0,#file_name,0); //<2F><><EFBFBD><EFBFBD><EFBFBD> <20><><EFBFBD>
		}
	ELSE
		{
			WriteText(164+dform_x,190,0x80,0,"...?",0);
			WriteText(dform_x+20,190,0,0,#file_name,24); //<2F><><EFBFBD><EFBFBD><EFBFBD> <20><><EFBFBD>
		}
	//<2F><><EFBFBD><EFBFBD><EFBFBD><EFBFBD><EFBFBD><EFBFBD>
	DrawFlatButton(dform_x+20,208,70,20,301,0xFFB6B5,"Yes");
	DrawFlatButton(dform_x+111,208,70,20,302,0xC6DFC6,"No");
	del_active=1;
}

	
void Del_File(byte dodel)
{    
	int del_file_rez;
	IF (dodel==true)
	{
		del_file_rez=DeleleFile(#file_path);
		IF (del_file_rez<>0)
		{
			Write_Error(del_file_rez);
			IF (isdir==true) ShowMessage("Error. Folder isn't empty.");
			IF (isdir==false) ShowMessage("Error. Filesystem read-only.");
		}
 	}
	del_active=0;
	DeleteButton(301); DeleteButton(302); //<2F><><EFBFBD><EFBFBD><EFBFBD><EFBFBD><EFBFBD> <20><><EFBFBD><EFBFBD><EFBFBD><EFBFBD><EFBFBD><EFBFBD> Yes/No
	Open_Dir(#path,1);
}    

void Paste()
{
	char new_copy_path[4096];
	int copy_rezult;
	
	IF (!copy_file) return; //<2F><><EFBFBD><EFBFBD><EFBFBD><EFBFBD>, <20><><EFBFBD> <20><><EFBFBD> <20><><EFBFBD><EFBFBD> <20><> <20><><EFBFBD><EFBFBD><EFBFBD><EFBFBD><EFBFBD><EFBFBD><EFBFBD><EFBFBD><EFBFBD>
	copystr(#path,#new_copy_path);
	copystr(#copy_file+strchr(#copy_file,'/'),#new_copy_path+strlen(#new_copy_path));
	if (!strcmp(#copy_file,#new_copy_path)) //<2F><><EFBFBD><EFBFBD> <20><> <20><><EFBFBD><EFBFBD><EFBFBD><EFBFBD><EFBFBD><EFBFBD> <20> <20><><EFBFBD><EFBFBD><EFBFBD><EFBFBD><EFBFBD><EFBFBD><EFBFBD> <20> <20><><EFBFBD><EFBFBD><EFBFBD> <20> <20><><EFBFBD> <20><> <20><><EFBFBD><EFBFBD><EFBFBD>
	{
		copystr(#path,#new_copy_path);
		copystr("new_",#new_copy_path+strlen(#new_copy_path));
		copystr(#copy_file+strchr(#copy_file,'/'),#new_copy_path+strlen(#new_copy_path));
	}
	copy_rezult=CopyFile(#copy_file,#new_copy_path);
	IF (copy_rezult<>0) //<2F><><EFBFBD><EFBFBD><EFBFBD><EFBFBD>
	{
		Write_Error(copy_rezult);
		DrawFlatButton(Form.width/2-13,160,200,80,0,0xFFB6B5, "Error. You can't paste here.");
		Pause(150);
	}
	IF (cut_active) //<2F><><EFBFBD><EFBFBD> <20><> <20><><EFBFBD><EFBFBD><EFBFBD><EFBFBD><EFBFBD> <20><><EFBFBD><EFBFBD><EFBFBD><EFBFBD><EFBFBD><EFBFBD>
		{
			copystr(#copy_file,#file_path);
			Del_File(true);
			copy_file='';
			cut_active=0;
		}
	SelectFile(#new_copy_path+strchr(#new_copy_path,'/'));
}


void ReName(byte rename)
{
	int del_file_rez;
	char edit_name[256];
	rename_active=0;
	edit2.flags=64;
	DefineButton(192,curbtn*BUTTON_HEIGHT+57,onLeft(27,192),BUTTON_HEIGHT,curbtn+201+BT_HIDE+BT_NOFRAME,0xFFFFFF);
	if (rename==true)
	{
		copystr(#path,#temp);
		copystr(#file_name,#edit_name); //<2F><><EFBFBD><EFBFBD><EFBFBD><EFBFBD><EFBFBD><EFBFBD><EFBFBD> <20><><EFBFBD><EFBFBD><EFBFBD> <20><><EFBFBD> <20><><EFBFBD><EFBFBD><EFBFBD>, <20><><EFBFBD> <20><><EFBFBD><EFBFBD>, <20><><EFBFBD><EFBFBD><EFBFBD> <20><><EFBFBD> <20><><EFBFBD><EFBFBD><EFBFBD> <20><><EFBFBD><EFBFBD><EFBFBD><EFBFBD><EFBFBD><EFBFBD>
		copystr(#file_name,#temp+strlen(#temp));
		if (strcmp(#file_path,#temp)<>0) && (file_name)
		IF (isdir)
		{
			del_file_rez=DeleleFile(#file_path);
			IF (del_file_rez<>0)
			{
				Write_Error(del_file_rez);
				ShowMessage("Error. Folder isn't empty.");
				return;
			}
			ELSE CreateFolder(#temp);
			Open_Dir(#path,1);
		}
		ELSE
		{
			CopyFile(#file_path,#temp);
			Del_File(true);
		}
		SelectFile(#edit_name);
	}
	Line_ReDraw(selection_col,curbtn);
}



void Goto_edit_path()
{
	IF (!strcmp(#path,#edit_path)) return; //<2F><><EFBFBD><EFBFBD><EFBFBD><EFBFBD><EFBFBD><EFBFBD> <20><> <20> <20><><EFBFBD><EFBFBD> <20><> <20><> <20><><EFBFBD><EFBFBD><EFBFBD>
 	IF (strcmp(#edit_path+strlen(#edit_path)-1,"/")<>0) copystr("/",#edit_path+strlen(#edit_path)); //<2F><><EFBFBD><EFBFBD> <20><><EFBFBD>, + "/"
	Open_Dir(#edit_path,ONLY_OPEN); //<2F><><EFBFBD><EFBFBD><EFBFBD><EFBFBD><EFBFBD><EFBFBD><EFBFBD> <20><><EFBFBD><EFBFBD> <20><><EFBFBD><EFBFBD><EFBFBD> <20> <20><><EFBFBD><EFBFBD><EFBFBD>, <20><><EFBFBD> <20><> <20><><EFBFBD><EFBFBD><EFBFBD><EFBFBD> <20><><EFBFBD><EFBFBD><EFBFBD><EFBFBD><EFBFBD><EFBFBD><EFBFBD><EFBFBD> <20><> <20><><EFBFBD>
	IF (count<1)  
		KEdit(); //<2F><><EFBFBD><EFBFBD><EFBFBD><EFBFBD> <20><><EFBFBD><EFBFBD><EFBFBD><EFBFBD><EFBFBD> <20><><EFBFBD><EFBFBD><EFBFBD><EFBFBD> <20><><EFBFBD><EFBFBD><EFBFBD><EFBFBD>
	ELSE
	{
		za_kadrom=curbtn=0; //<2F><><EFBFBD><EFBFBD><EFBFBD><EFBFBD> <20><><EFBFBD><EFBFBD><EFBFBD><EFBFBD>
		copystr(#edit_path,#path);
	}
	Open_Dir(#path,1);
}

void SelectFile(dword that_file)
{
	za_kadrom=curbtn=0; //<2F><><EFBFBD><EFBFBD><EFBFBD> <20><><EFBFBD><EFBFBD><EFBFBD><EFBFBD>
   	Open_Dir(#path,ONLY_OPEN);
	TitleCase(that_file);
	for (i=count-1; i>=0; i--;)
		if (!strcmp(file_mas[i]*304+buf+72,that_file)) break;
	FileList_ReDraw(i);
	List_ReDraw();
}


void Dir_Up()
{
	char cur_folder[4096];
	if (!strcmp(#path,"/")) return;
	i=strlen(#path)-1;
	path[i]=0x00;
	do i--; while (path[i]<>'/'); copystr(#path+i+1,#cur_folder); 
	path[i+1]=0x00;
	SelectFile(#cur_folder);
}


inline fastcall void GoBack()   //<2F><><EFBFBD><EFBFBD><EFBFBD><EFBFBD><EFBFBD> <20><><EFBFBD><EFBFBD><EFBFBD><EFBFBD><EFBFBD> <20><><EFBFBD><EFBFBD><EFBFBD><EFBFBD><EFBFBD> <20><><EFBFBD><EFBFBD>, <20> <20><><EFBFBD><EFBFBD><EFBFBD> <20><><EFBFBD><EFBFBD><EFBFBD><EFBFBD><EFBFBD><EFBFBD> <20><>, <20><><EFBFBD> <20><><EFBFBD><EFBFBD><EFBFBD><EFBFBD><EFBFBD><EFBFBD>
{
	char cur_folder[4096];
	copystr(GetCurrentFolder(), #cur_folder);
	if (HistoryPath(GO_BACK))
		SelectFile(#cur_folder);
}


stop: