(*
    BSD 2-Clause License

    Copyright (c) 2019-2020, Anton Krotov
    All rights reserved.
*)

MODULE TARGETS;


CONST

    MSP430*       =  0;
    Win32C*       =  1;
    Win32GUI*     =  2;
    Win32DLL*     =  3;
    KolibriOS*    =  4;
    KolibriOSDLL* =  5;
    Win64C*       =  6;
    Win64GUI*     =  7;
    Win64DLL*     =  8;
    Linux32*      =  9;
    Linux32SO*    = 10;
    Linux64*      = 11;
    Linux64SO*    = 12;
    STM32CM3*     = 13;

    cpuX86* = 0; cpuAMD64* = 1; cpuMSP430* = 2; cpuTHUMB* = 3;

    osNONE*    = 0;  osWIN32*   = 1;  osWIN64* = 2;
    osLINUX32* = 3;  osLINUX64* = 4;  osKOS*   = 5;


TYPE

    STRING = ARRAY 32 OF CHAR;

    TARGET = RECORD

        target, CPU, BitDepth, OS, RealSize: INTEGER;
        ComLinePar*, LibDir, FileExt: STRING

    END;


VAR

    Targets*: ARRAY 14 OF TARGET;

    target*, CPU*, BitDepth*, OS*, RealSize*, WordSize*, AdrSize*: INTEGER;
    ComLinePar*, LibDir*, FileExt*: STRING;
    Import*, Dispose*, Dll*: BOOLEAN;


PROCEDURE Enter (idx, CPU, BitDepth, RealSize, OS: INTEGER; ComLinePar, LibDir, FileExt: STRING);
BEGIN
    Targets[idx].target := idx;
    Targets[idx].CPU := CPU;
    Targets[idx].BitDepth := BitDepth;
    Targets[idx].RealSize := RealSize;
    Targets[idx].OS := OS;
    Targets[idx].ComLinePar := ComLinePar;
    Targets[idx].LibDir := LibDir;
    Targets[idx].FileExt := FileExt;
END Enter;


PROCEDURE Select* (ComLineParam: ARRAY OF CHAR): BOOLEAN;
VAR
    i: INTEGER;
    res: BOOLEAN;

BEGIN
    i := 0;
    WHILE (i < LEN(Targets)) & (Targets[i].ComLinePar # ComLineParam) DO
        INC(i)
    END;

    res := i < LEN(Targets);
    IF res THEN
        target := Targets[i].target;
        CPU := Targets[i].CPU;
        BitDepth := Targets[i].BitDepth;
        RealSize := Targets[i].RealSize;
        OS := Targets[i].OS;
        ComLinePar := Targets[i].ComLinePar;
        LibDir := Targets[i].LibDir;
        FileExt := Targets[i].FileExt;

        Import := OS IN {osWIN32, osWIN64, osKOS};
        Dispose := ~(target IN {MSP430, STM32CM3});
        Dll := target IN {Linux32SO, Linux64SO, Win32DLL, Win64DLL, KolibriOSDLL};
        WordSize := BitDepth DIV 8;
        AdrSize  := WordSize
    END

    RETURN res
END Select;


BEGIN
    Enter( MSP430,        cpuMSP430,  16,  0,  osNONE,     "msp430",      "MSP430",     ".hex");
    Enter( Win32C,        cpuX86,     32,  8,  osWIN32,    "win32con",    "Windows32",  ".exe");
    Enter( Win32GUI,      cpuX86,     32,  8,  osWIN32,    "win32gui",    "Windows32",  ".exe");
    Enter( Win32DLL,      cpuX86,     32,  8,  osWIN32,    "win32dll",    "Windows32",  ".dll");
    Enter( KolibriOS,     cpuX86,     32,  8,  osKOS,      "kosexe",      "KolibriOS",  "");
    Enter( KolibriOSDLL,  cpuX86,     32,  8,  osKOS,      "kosdll",      "KolibriOS",  ".obj");
    Enter( Win64C,        cpuAMD64,   64,  8,  osWIN64,    "win64con",    "Windows64",  ".exe");
    Enter( Win64GUI,      cpuAMD64,   64,  8,  osWIN64,    "win64gui",    "Windows64",  ".exe");
    Enter( Win64DLL,      cpuAMD64,   64,  8,  osWIN64,    "win64dll",    "Windows64",  ".dll");
    Enter( Linux32,       cpuX86,     32,  8,  osLINUX32,  "linux32exe",  "Linux32",    "");
    Enter( Linux32SO,     cpuX86,     32,  8,  osLINUX32,  "linux32so",   "Linux32",    ".so");
    Enter( Linux64,       cpuAMD64,   64,  8,  osLINUX64,  "linux64exe",  "Linux64",    "");
    Enter( Linux64SO,     cpuAMD64,   64,  8,  osLINUX64,  "linux64so",   "Linux64",    ".so");
    Enter( STM32CM3,      cpuTHUMB,   32,  4,  osNONE,     "stm32cm3",    "STM32CM3",   ".hex");
END TARGETS.